Oracle - Employee Salary Information

Organisations can utilize the Xtend IVR system to automate their employee salary information. Employees can call IVR and directly retrieve information related to their salary. Apart from reducing the workload of the staff this approach provides a faster way for accessing the salary details.

Download the evaluation version of Xtend IVR and install the telephony application in your system. Run the sample script from the Script Editor. Click here to refer the code.

The automated attendant will work as given below:

• IVR waits for the call
• Caller dials the number, IVR accepts the call and plays the Welcome message
• IVR asks the employee to enter the Employee Number and Department Number
• Validates the entries in the database and informs the salary to the employee

Download the source file for the Employee Salary Information using Oracle

***************************************************************
* Script: Employee.dt
* Notes : welcomes the user
*         accepts the employee number
*         accepts the depart number
*         query an Oracle database (default oracle database)
*         and retrive the employee salary
***************************************************************

// ADO Connect string for database SCOTT
$db = "Provider=MSDAORA.1;User ID=scott;Password=tiger;Data Source=xtendora;
							Persist Security Info=False"
				
// All inputs are configured for not more than two retry attempts
$retrycount = 2
MAIN:
	display "Waiting for call . . ."
	
	// Pickup the call after the first ring
	answer 1
	
	* Welcome user
	play "Welcome.wav"
	play "silence.wav"
	
ACCEPT_ACCNO:
	display "Accept employee number"
	play "silence.wav"
	$retry = $retrycount
	while $retry > 0
		play "empno.wav"
		$EmpNo = Input(4,5)
		if $EmpNo = ""
			* Advice the caller to enable TONE mode
			* in his telephone (Do it only once)
			if $retry = $retrycount
				play "advice.wav"
			endif
		else
			break
		endif
		$retry -= 1
	endwhile
	if $EmpNo = "" then goto GOODBYE
	
ACCEPT_PIN:
	display "Accept DEPT number"
	play "silence.wav"
	$retry = $retrycount
	while $retry > 0
		play "department.wav"
		$DeptNo = Input(2,5)
		if $DeptNo <> ""
			break
		endif
		$retry -= 1
	endwhile
	if $DeptNo == "" then goto GOODBYE
	
	display "Validating User"
	
	* Run SQL
	$sql = format("select * from EMP where EMPNO = %d and DEPTNO = %d",$EmpNo,$DeptNo)
	$dbalias = db.RunSQL($db, $sql)
	if $dbalias.eof
		play "notfound.wav"
		goto GOODBYE
	endif
	display $dbalias.ENAME
	play "salary.wav"
	
	* Speak out the results to the caller
	$wave = Money2Wav($dbalias.SAL)
	play $wave
	wait 0

GOODBYE:
	* Thank you message
	display "Terminating Call"
	play "silence.wav"
	play "goodbye.wav"
	hangup
	goto MAIN

* User has hung up
ONHANGUP:
	hangup
	goto MAIN

* An error has occurred
ONSYSTEMERROR:
	log $error
	display $error
	hangup
	goto MAIN

* End of Script